@echo off
rem Podgotovka dostupov rukovoditelei depo po spisku dostupy.xlsx.
rem
rem Bez parametra - tolko PROVERKA: nichego ne zapisyvaet, pechataet itog
rem i sohranyaet otchet out\dostupy_otchet.xlsx.
rem     import_access.cmd
rem Zapisat v bazu:
rem     import_access.cmd apply
rem
rem Paroli NIKOMU NE OTPRAVLYAYUTSYA i nigde ne pokazyvayutsya. Vydat dostup -
rem v kartochke sotrudnika knopkoi "Smenit parol i vyslat".
rem Spisok ishetsya ryadom s papkoi tabel: ..\dostupy.xlsx
rem Baza dolzhna byt zapushena (start_app.cmd).
cd /d "%~dp0"
title Podgotovka dostupov OOUCR

set "PYEXE=%~dp0engine\.venv\Scripts\python.exe"
if not exist "%PYEXE%" goto no_python
set "DATABASE_URL=postgresql://postgres:postgres@127.0.0.1:5434/ooucr"
set "LIST=%~dp0..\dostupy.xlsx"
if not exist "%LIST%" set "LIST=%~dp0dostupy.xlsx"
if not exist "%LIST%" goto no_list

if /i "%~1"=="apply" goto apply
"%PYEXE%" "%~dp0tools\import_access.py" --file "%LIST%"
goto after
:apply
"%PYEXE%" "%~dp0tools\import_access.py" --file "%LIST%" --apply
:after
echo.
echo Otchet: out\dostupy_otchet.xlsx
echo.
pause
exit /b 0

:no_list
echo.
echo Ne naiden spisok dostupy.xlsx - polozhite ego ryadom s papkoi
echo prilozheniya ili vnutr nee.
echo.
pause
exit /b 1

:no_python
echo.
echo Ne naideno okruzhenie prilozheniya:
echo   %PYEXE%
echo Snachala zapustite start_app.cmd - on sozdaet okruzhenie.
echo.
pause
exit /b 1
